VBScriptでAccessのクエリの値を変更するサンプルコード

Accessのクエリ内の値を変更したいって思うことがあると思います。

でも手動で変更するのは、変更する対象が多いと大変で面倒です。

そんなときは、当記事のサンプルコードをコピペして利用することで、簡単かついっぺんに値を変更できます。

サンプルコードは、私自身が作成したオリジナルのプログラムです。

定数は大文字じゃないといった皆さん自身のルールがあるかもしれませんがご理解ください。

当記事は、実践編としてVBScriptの基本的な文法がわかる中級者の方にご紹介しています。

基本的な文法がわからない方は、初級編の記事も紹介しているのでそちらを参考にしてください。

各クエリの値を変更する

各クエリの値を変更する

サンプルコード

'【定数】
Const REPLACE_MAE = "置換前"
Const REPLACE_ATO = "置換後"

'ファイルシステムオブジェクト作成
Dim objFso : Set objFso = CreateObject("Scripting.FileSystemObject")
'vbsフォルダーパス
Dim PATH_DIR_VBS : PATH_DIR_VBS = objFso.GetAbsolutePathname(".") & "\"
'Accessフルパス
Dim PATH_FULL_MDB : PATH_FULL_MDB = PATH_DIR_VBS & "Query.mdb"
'後始末
Set objFso = Nothing

'Accessを作成
Dim objAccess : Set objAccess = CreateObject("Access.Application")
'Accessを非表示に設定
objAccess.Visible = false
'Accessを開く
objAccess.OpenCurrentDatabase PATH_FULL_MDB

'クエリの数だけループする
For Each querie In objAccess.CurrentData.AllQueries
	'クエリ名取得
	Dim strQueryNm : strQueryNm = querie.Name
	'クエリに置換前の文字が含まれるかチェック
	If InStr(objAccess.CurrentDb().QueryDefs(strQueryNm).SQL,REPLACE_MAE) > 0 Then
		'置換
		objAccess.CurrentDb().QueryDefs(strQueryNm).SQL = Replace(objAccess.CurrentDb().QueryDefs(strQueryNm).SQL,REPLACE_MAE,REPLACE_ATO)
	Else
	End If
	'クエリを閉じる
	objAccess.CurrentDb().QueryDefs(strQueryNm).Close()
Next

'Accessを閉じる
objAccess.Quit
'後始末
Set objAccess = Nothing